bd89b6d126
- renamed DrawTitle to DisplayTitle --HG-- extra : convert_revision : svn%3A39bc706e-5318-0410-9160-8a85361fbb7c/trunk%401531
125 lines
2.6 KiB
SourcePawn
125 lines
2.6 KiB
SourcePawn
|
|
PerformKick(client, target, const String:reason[])
|
|
{
|
|
decl String:name[MAX_NAME_LENGTH];
|
|
|
|
GetClientName(target, name, sizeof(name));
|
|
|
|
ShowActivity(client, "%t", "Kicked player", name);
|
|
LogAction(client, target, "\"%L\" kicked \"%L\" (reason \"%s\")", client, target, reason);
|
|
|
|
if (reason[0] == '\0')
|
|
{
|
|
KickClient(target, "%t", "Kicked by admin");
|
|
}
|
|
else
|
|
{
|
|
KickClient(target, "%s", reason);
|
|
}
|
|
}
|
|
|
|
DisplayKickMenu(client)
|
|
{
|
|
new Handle:menu = CreateMenu(MenuHandler_Kick);
|
|
|
|
decl String:title[100];
|
|
Format(title, sizeof(title), "%T:", "Kick player", client);
|
|
SetMenuTitle(menu, title);
|
|
SetMenuExitBackButton(menu, true);
|
|
|
|
AddTargetsToMenu(menu, client, false);
|
|
|
|
DisplayMenu(menu, client, MENU_TIME_FOREVER);
|
|
}
|
|
|
|
public AdminMenu_Kick(Handle:topmenu,
|
|
TopMenuAction:action,
|
|
TopMenuObject:object_id,
|
|
param,
|
|
String:buffer[],
|
|
maxlength)
|
|
{
|
|
if (action == TopMenuAction_DisplayOption)
|
|
{
|
|
Format(buffer, maxlength, "%T", "Kick player", param);
|
|
}
|
|
else if (action == TopMenuAction_SelectOption)
|
|
{
|
|
DisplayKickMenu(param);
|
|
}
|
|
}
|
|
|
|
public MenuHandler_Kick(Handle:menu, MenuAction:action, param1, param2)
|
|
{
|
|
if (action == MenuAction_End)
|
|
{
|
|
CloseHandle(menu);
|
|
}
|
|
else if (action == MenuAction_Cancel)
|
|
{
|
|
if (param2 == MenuCancel_ExitBack && hTopMenu != INVALID_HANDLE)
|
|
{
|
|
DisplayTopMenu(hTopMenu, param1, TopMenuPosition_LastCategory);
|
|
}
|
|
}
|
|
else if (action == MenuAction_Select)
|
|
{
|
|
decl String:info[32];
|
|
new userid, target;
|
|
|
|
GetMenuItem(menu, param2, info, sizeof(info));
|
|
userid = StringToInt(info);
|
|
|
|
if ((target = GetClientOfUserId(userid)) == 0)
|
|
{
|
|
PrintToChat(param1, "[SM] %t", "Player no longer available");
|
|
}
|
|
else if (!CanUserTarget(param1, target))
|
|
{
|
|
PrintToChat(param1, "[SM] %t", "Unable to target");
|
|
}
|
|
else
|
|
{
|
|
PerformKick(param1, target, "");
|
|
}
|
|
|
|
/* Re-draw the menu if they're still valid */
|
|
if (IsClientInGame(param1) && !IsClientInKickQueue(param1))
|
|
{
|
|
DisplayKickMenu(param1);
|
|
}
|
|
}
|
|
}
|
|
|
|
public Action:Command_Kick(client, args)
|
|
{
|
|
if (args < 1)
|
|
{
|
|
ReplyToCommand(client, "[SM] Usage: sm_kick <#userid|name> [reason]");
|
|
return Plugin_Handled;
|
|
}
|
|
|
|
decl String:Arguments[256];
|
|
GetCmdArgString(Arguments, sizeof(Arguments));
|
|
|
|
decl String:arg[65];
|
|
new len = BreakString(Arguments, arg, sizeof(arg));
|
|
|
|
new target = FindTarget(client, arg);
|
|
if (target == -1)
|
|
{
|
|
return Plugin_Handled;
|
|
}
|
|
|
|
if (len == -1)
|
|
{
|
|
/* Safely null terminate */
|
|
len = 0;
|
|
Arguments[0] = '\0';
|
|
}
|
|
|
|
PerformKick(client, target, Arguments[len]);
|
|
|
|
return Plugin_Handled;
|
|
}
|