UNLOZE/sourcemod
9
0
Fork 0
Code Issues Pull Requests Releases Wiki Activity

Port TopMenus to transitional syntax.

Browse Source
This commit is contained in:
David Anderson
2014-10-30 19:20:33 -07:00
committed by David Anderson
parent e5eb291b67
commit b97335ccb0
34 changed files with 334 additions and 387 deletions
Download Patch File Download Diff File Expand all files Collapse all files
plugins/include/adminmenu.inc
+3 -3
View File
@@ -65,7 +65,7 @@
* @param topmenu Handle to the admin menu's TopMenu.
* @noreturn
*/
forward OnAdminMenuCreated(Handle:topmenu);
forward OnAdminMenuCreated(TopMenu topmenu);
/**
* Called when the admin menu is ready to have items added.
@@ -73,7 +73,7 @@ forward OnAdminMenuCreated(Handle:topmenu);
* @param topmenu Handle to the admin menu's TopMenu.
* @noreturn
*/
forward OnAdminMenuReady(Handle:topmenu);
forward OnAdminMenuReady(TopMenu topmenu);
/**
* Retrieves the Handle to the admin top menu.
@@ -81,7 +81,7 @@ forward OnAdminMenuReady(Handle:topmenu);
* @return Handle to the admin menu's TopMenu,
* or INVALID_HANDLE if not created yet.
*/
native Handle:GetAdminTopMenu();
native TopMenu GetAdminTopMenu();
/**
* Adds targets to an admin menu.
plugins/include/topmenus.inc
+141 -25
View File
@@ -1,5 +1,5 @@
/**
* vim: set ts=4 :
* vim: set ts=4 sw=4 tw=99 noet:
* =============================================================================
* SourceMod (C)2004-2008 AlliedModders LLC. All rights reserved.
* =============================================================================
@@ -40,7 +40,7 @@
/**
* Actions a top menu will take on an topobj.
*/
enum TopMenuAction
enum TopMenuAction:
{
/**
* An option is being drawn for a menu (or for sorting purposes).
@@ -92,7 +92,7 @@ enum TopMenuAction
/**
* Top menu topobj types.
*/
enum TopMenuObjectType
enum TopMenuObjectType:
{
TopMenuObject_Category = 0, /**< Category (sub-menu branching from root) */
TopMenuObject_Item = 1 /**< Item on a sub-menu */
@@ -101,7 +101,7 @@ enum TopMenuObjectType
/**
* Top menu starting positions for display.
*/
enum TopMenuPosition
enum TopMenuPosition:
{
TopMenuPosition_Start = 0, /**< Start/root of the menu */
TopMenuPosition_LastRoot = 1, /**< Last position in the root menu */
@@ -111,7 +111,7 @@ enum TopMenuPosition
/**
* Top menu topobj tag for type checking.
*/
enum TopMenuObject
enum TopMenuObject:
{
INVALID_TOPMENUOBJECT = 0,
};
@@ -136,13 +136,126 @@ typedef TopMenuHandler = function void (
int maxlength
);
// TopMenu objects are used for constructing multi-layer menus. Currently, they
// support at most two levels. The first level of items are called "categories".
methodmap TopMenu < Handle
{
// Creates a new TopMenu.
//
// @param handler Handler to use for drawing the root title.
// @return A new TopMenu.
public native TopMenu(TopMenuHandler handler);
// Re-sorts the items in a TopMenu via a configuration file.
//
// The format of the configuration file should be a Valve Key-Values
// formatted file that SourceMod can parse. There should be one root
// section, and one sub-section for each category. Each sub-section's
// name should match the category name.
//
// Each sub-section may only contain key/value pairs in the form of:
// key: "item"
// value: Name of the item as passed to AddToTopMenu().
//
// The TopMenu will draw items in the order declared in the configuration
// file. If items do not appear in the configuration file, they are sorted
// per-player based on how the handler function renders for that player.
// These items appear after the configuration sorted items.
//
// @param topmenu TopMenu Handle.
// @param file File path.
// @param error Error buffer.
// @param maxlength Maximum size of the error buffer. Error buffer
// will be filled with a zero-terminated string if
// false is returned.
// @return True on success, false on failure.
public native bool LoadConfig(const char[] file, char[] error, int maxlength);
// Adds a category to a TopMenu.
//
// @param name Object name (MUST be unique).
// @param handler Handler for topobj.
// @param cmdname Command name (for access overrides).
// @param flags Default access flags.
// @param info_string Arbitrary storage (max 255 bytes).
// @return A new TopMenuObject ID, or INVALID_TOPMENUOBJECT on failure.
public native TopMenuObject AddCategory(const char[] name, TopMenuHandler handler,
const char[] cmdname = "", int flags = 0,
const char[] info_string = "");
// Adds an item to a TopMenu category.
//
// @param name Object name (MUST be unique).
// @param handler Handler for topobj.
// @param category The object of the parent category for the item.
// @param cmdname Command name (for access overrides).
// @param flags Default access flags.
// @param info_string Arbitrary storage (max 255 bytes).
// @return A new TopMenuObject ID, or INVALID_TOPMENUOBJECT on failure.
public native TopMenuObject AddItem(const char[] name, TopMenuHandler handler,
TopMenuObject parent, const char[] cmdname = "",
int flags = 0, const char[] info_string = "");
// Retrieves the info string of a top menu item.
//
// @param parent TopMenuObject ID.
// @param buffer Buffer to store info string.
// @param maxlength Maximum size of info string.
// @return Number of bytes written, not including the null terminator.
public native int GetInfoString(TopMenuObject parent, char[] buffer, int maxlength);
// Retrieves the name string of a top menu item.
//
// @param topobj TopMenuObject ID.
// @param buffer Buffer to store info string.
// @param maxlength Maximum size of info string.
// @return Number of bytes written, not including the null terminator.
public native int GetObjName(TopMenuObject topobj, char[] buffer, int maxlength);
// Removes an topobj from a TopMenu.
//
// Plugins' topobjs are automatically removed all TopMenus when the given
// plugin unloads or pauses. In the case of unpausing, all items are restored.
//
// @param topobj TopMenuObject ID.
public native void Remove(TopMenuObject topobj);
// Displays a TopMenu to a client.
//
// @param client Client index.
// @param position Position to display from.
// @return True on success, false on failure.
public native bool Display(int client, TopMenuPosition position);
// Displays a TopMenu category to a client.
//
// @param category Category topobj id.
// @param client Client index.
// @return True on success, false on failure.
public native bool DisplayCategory(TopMenuObject category, int client);
// Finds a category's topobj ID in a TopMenu.
//
// @param name Object's unique name.
// @return TopMenuObject ID on success, or
// INVALID_TOPMENUOBJECT on failure.
public native TopMenuObject FindCategory(const char[] name);
// Set the menu title caching behaviour of the TopMenu. By default titles
// are cached to reduce overhead. If you need dynamic menu titles which
// change each time the menu is displayed to a user, set this to false.
property bool CacheTitles {
public native set(bool value);
}
};
/**
* Creates a TopMenu.
*
* @param handler Handler to use for drawing the root title.
* @return A new TopMenu Handle, or INVALID_HANDLE on failure.
*/
native Handle:CreateTopMenu(TopMenuHandler:handler);
native TopMenu CreateTopMenu(TopMenuHandler handler);
/**
* Re-sorts the items in a TopMenu via a configuration file.
@@ -171,7 +284,7 @@ native Handle:CreateTopMenu(TopMenuHandler:handler);
* @return True on success, false on failure.
* @error Invalid TopMenu Handle.
*/
native bool:LoadTopMenuConfig(Handle:topmenu, const String:file[], String:error[], maxlength);
native bool LoadTopMenuConfig(Handle topmenu, const char[] file, char[] error, int maxlength);
/**
* Adds an topobj to a TopMenu.
@@ -190,14 +303,14 @@ native bool:LoadTopMenuConfig(Handle:topmenu, const String:file[], String:error[
* failure.
* @error Invalid TopMenu Handle.
*/
native TopMenuObject:AddToTopMenu(Handle:topmenu,
const String:name[],
TopMenuObjectType:type,
TopMenuHandler:handler,
TopMenuObject:parent,
const String:cmdname[]="",
flags=0,
const String:info_string[]="");
native TopMenuObject AddToTopMenu(Handle topmenu,
const char[] name,
TopMenuObjectType type,
TopMenuHandler handler,
TopMenuObject parent,
const char[] cmdname="",
int flags=0,
const char[] info_string="");
/**
* Retrieves the info string of a top menu item.
@@ -210,7 +323,7 @@ native TopMenuObject:AddToTopMenu(Handle:topmenu,
* null terminator.
* @error Invalid TopMenu Handle or TopMenuObject ID.
*/
native GetTopMenuInfoString(Handle:topmenu, TopMenuObject:parent, String:buffer[], maxlength);
native int GetTopMenuInfoString(Handle topmenu, TopMenuObject parent, char[] buffer, int maxlength);
/**
* Retrieves the name string of a top menu item.
@@ -223,7 +336,7 @@ native GetTopMenuInfoString(Handle:topmenu, TopMenuObject:parent, String:buffer[
* null terminator.
* @error Invalid TopMenu Handle or TopMenuObject ID.
*/
native GetTopMenuObjName(Handle:topmenu, TopMenuObject:topobj, String:buffer[], maxlength);
native int GetTopMenuObjName(Handle topmenu, TopMenuObject topobj, char[] buffer, int maxlength);
/**
* Removes an topobj from a TopMenu.
@@ -236,7 +349,7 @@ native GetTopMenuObjName(Handle:topmenu, TopMenuObject:topobj, String:buffer[],
* @noreturn
* @error Invalid TopMenu Handle.
*/
native RemoveFromTopMenu(Handle:topmenu, TopMenuObject:topobj);
native void RemoveFromTopMenu(Handle topmenu, TopMenuObject topobj);
/**
* Displays a TopMenu to a client.
@@ -247,7 +360,7 @@ native RemoveFromTopMenu(Handle:topmenu, TopMenuObject:topobj);
* @return True on success, false on failure.
* @error Invalid TopMenu Handle or client not in game.
*/
native bool:DisplayTopMenu(Handle:topmenu, client, TopMenuPosition:position);
native bool DisplayTopMenu(Handle topmenu, int client, TopMenuPosition position);
/**
* Displays a TopMenu category to a client.
@@ -258,7 +371,7 @@ native bool:DisplayTopMenu(Handle:topmenu, client, TopMenuPosition:position);
* @return True on success, false on failure.
* @error Invalid TopMenu Handle or client not in game.
*/
native bool:DisplayTopMenuCategory(Handle:topmenu, TopMenuObject:category, client);
native bool DisplayTopMenuCategory(Handle topmenu, TopMenuObject category, int client);
/**
* Finds a category's topobj ID in a TopMenu.
@@ -269,18 +382,21 @@ native bool:DisplayTopMenuCategory(Handle:topmenu, TopMenuObject:category, clien
* INVALID_TOPMENUOBJECT on failure.
* @error Invalid TopMenu Handle.
*/
native TopMenuObject:FindTopMenuCategory(Handle:topmenu, const String:name[]);
native TopMenuObject FindTopMenuCategory(Handle topmenu, const char[] name);
/**
* Change the menu title caching behaviour of the TopMenu. By default the titles are cached to reduce overhead.
* If you need dynamic menu titles, which can change everytime the menu is displayed to a user, set this to false.
* Change the menu title caching behaviour of the TopMenu. By default the
* titles are cached to reduce overhead. If you need dynamic menu titles, which
* can change everytime the menu is displayed to a user, set this to false.
*
* @param topmenu TopMenu Handle.
* @param cache_titles Cache the menu titles and don't call the handler with TopMenuAction_DisplayTitle everytime the menu is drawn?
* @param cache_titles Cache the menu titles and don't call the handler with
* TopMenuAction_DisplayTitle everytime the menu is drawn?
* @noreturn
* @error Invalid TopMenu Handle
*/
native SetTopMenuTitleCaching(Handle:topmenu, bool:cache_titles);
native void SetTopMenuTitleCaching(Handle topmenu, bool cache_titles);
/**
* Do not edit below this line!