Spring Cleaning, Part Ichi (1)

Various minor things done to project files Updated sample extension project file and updated makefile to the new unified version (more changes likely on the way) Updated regex project file and makefile --HG-- extra : convert_revision : svn%3A39bc706e-5318-0410-9160-8a85361fbb7c/trunk%401971
2008-03-30 07:00:22 +00:00
commit 251cced1f8
801 changed files with 280074 additions and 0 deletions
@@ -0,0 +1,182 @@
+/**
+ * vim: set ts=4 :
+ * =============================================================================
+ * SourceMod Basevotes Plugin
+ * Provides ban functionality
+ *
+ * SourceMod (C)2004-2008 AlliedModders LLC.  All rights reserved.
+ * =============================================================================
+ *
+ * This program is free software; you can redistribute it and/or modify it under
+ * the terms of the GNU General Public License, version 3.0, as published by the
+ * Free Software Foundation.
+ * 
+ * This program is distributed in the hope that it will be useful, but WITHOUT
+ * ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
+ * FOR A PARTICULAR PURPOSE.  See the GNU General Public License for more
+ * details.
+ *
+ * You should have received a copy of the GNU General Public License along with
+ * this program.  If not, see <http://www.gnu.org/licenses/>.
+ *
+ * As a special exception, AlliedModders LLC gives you permission to link the
+ * code of this program (as well as its derivative works) to "Half-Life 2," the
+ * "Source Engine," the "SourcePawn JIT," and any Game MODs that run on software
+ * by the Valve Corporation.  You must obey the GNU General Public License in
+ * all respects for all other code used.  Additionally, AlliedModders LLC grants
+ * this exception to all derivative works.  AlliedModders LLC defines further
+ * exceptions, found in LICENSE.txt (as of this writing, version JULY-31-2007),
+ * or <http://www.sourcemod.net/license.php>.
+ *
+ * Version: $Id: admin-flatfile.sp 1438 2007-09-16 03:45:06Z dvander $
+ */
+
+DisplayVoteBanMenu(client, target)
+{
+	g_voteClient[VOTE_CLIENTID] = target;
+	g_voteClient[VOTE_USERID] = GetClientUserId(target);
+
+	GetClientName(target, g_voteInfo[VOTE_NAME], sizeof(g_voteInfo[]));
+	GetClientAuthString(target, g_voteInfo[VOTE_AUTHID], sizeof(g_voteInfo[]));
+	GetClientIP(target, g_voteInfo[VOTE_IP], sizeof(g_voteInfo[]));
+
+	LogAction(client, target, "\"%L\" initiated a ban vote against \"%L\"", client, target);
+	ShowActivity2(client, "[SM] ", "%t", "Initiated Vote Ban", g_voteInfo[VOTE_NAME]);
+
+	g_voteType = voteType:ban;
+	
+	g_hVoteMenu = CreateMenu(Handler_VoteCallback, MenuAction:MENU_ACTIONS_ALL);
+	SetMenuTitle(g_hVoteMenu, "Voteban Player");
+	AddMenuItem(g_hVoteMenu, VOTE_YES, "Yes");
+	AddMenuItem(g_hVoteMenu, VOTE_NO, "No");
+	SetMenuExitButton(g_hVoteMenu, false);
+	VoteMenuToAll(g_hVoteMenu, 20);
+}
+
+DisplayBanTargetMenu(client)
+{
+	new Handle:menu = CreateMenu(MenuHandler_Ban);
+	
+	decl String:title[100];
+	Format(title, sizeof(title), "%T:", "Ban vote", client);
+	SetMenuTitle(menu, title);
+	SetMenuExitBackButton(menu, true);
+	
+	AddTargetsToMenu(menu, client, false, false);
+	
+	DisplayMenu(menu, client, MENU_TIME_FOREVER);
+}
+
+public AdminMenu_VoteBan(Handle:topmenu, 
+							  TopMenuAction:action,
+							  TopMenuObject:object_id,
+							  param,
+							  String:buffer[],
+							  maxlength)
+{
+	if (action == TopMenuAction_DisplayOption)
+	{
+		Format(buffer, maxlength, "%T", "Ban vote", param);
+	}
+	else if (action == TopMenuAction_SelectOption)
+	{
+		DisplayBanTargetMenu(param);
+	}
+	else if (action == TopMenuAction_DrawOption)
+	{	
+		/* disable this option if a vote is already running */
+		buffer[0] = !IsNewVoteAllowed() ? ITEMDRAW_IGNORE : ITEMDRAW_DEFAULT;
+	}
+}
+
+public MenuHandler_Ban(Handle:menu, MenuAction:action, param1, param2)
+{
+	if (action == MenuAction_End)
+	{
+		CloseHandle(menu);
+	}
+	else if (action == MenuAction_Cancel)
+	{
+		if (param2 == MenuCancel_ExitBack && hTopMenu != INVALID_HANDLE)
+		{
+			DisplayTopMenu(hTopMenu, param1, TopMenuPosition_LastCategory);
+		}
+	}
+	else if (action == MenuAction_Select)
+	{
+		decl String:info[32], String:name[32];
+		new userid, target;
+		
+		GetMenuItem(menu, param2, info, sizeof(info), _, name, sizeof(name));
+		userid = StringToInt(info);
+
+		if ((target = GetClientOfUserId(userid)) == 0)
+		{
+			PrintToChat(param1, "[SM] %t", "Player no longer available");
+		}
+		else if (!CanUserTarget(param1, target))
+		{
+			PrintToChat(param1, "[SM] %t", "Unable to target");
+		}
+		else
+		{
+			g_voteArg[0] = '\0';
+			DisplayVoteBanMenu(param1, target);
+		}
+	}
+}
+
+public Action:Command_Voteban(client, args)
+{
+	if (args < 1)
+	{
+		ReplyToCommand(client, "[SM] Usage: sm_voteban <player> [reason]");
+		return Plugin_Handled;	
+	}
+	
+	if (IsVoteInProgress())
+	{
+		ReplyToCommand(client, "[SM] %t", "Vote in Progress");
+		return Plugin_Handled;
+	}	
+	
+	if (!TestVoteDelay(client))
+	{
+		return Plugin_Handled;
+	}
+	
+	decl String:text[256], String:arg[64];
+	GetCmdArgString(text, sizeof(text));
+	
+	new len = BreakString(text, arg, sizeof(arg));
+	
+	if (len != -1)
+	{
+		strcopy(g_voteArg, sizeof(g_voteArg), text[len]);
+	}
+	else
+	{
+		g_voteArg[0] = '\0';
+	}
+	
+	decl String:target_name[MAX_TARGET_LENGTH];
+	decl target_list[MAXPLAYERS], target_count, bool:tn_is_ml;
+	
+	if ((target_count = ProcessTargetString(
+			arg,
+			client,
+			target_list,
+			MAXPLAYERS,
+			COMMAND_FILTER_NO_MULTI|COMMAND_FILTER_NO_BOTS,
+			target_name,
+			sizeof(target_name),
+			tn_is_ml)) <= 0)
+	{
+		ReplyToTargetError(client, target_count);
+		return Plugin_Handled;
+	}
+
+	DisplayVoteBanMenu(client, target_list[0]);
+	
+	return Plugin_Handled;
+}
@@ -0,0 +1,171 @@
+/**
+ * vim: set ts=4 :
+ * =============================================================================
+ * SourceMod Basevotes Plugin
+ * Provides kick functionality
+ *
+ * SourceMod (C)2004-2008 AlliedModders LLC.  All rights reserved.
+ * =============================================================================
+ *
+ * This program is free software; you can redistribute it and/or modify it under
+ * the terms of the GNU General Public License, version 3.0, as published by the
+ * Free Software Foundation.
+ * 
+ * This program is distributed in the hope that it will be useful, but WITHOUT
+ * ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
+ * FOR A PARTICULAR PURPOSE.  See the GNU General Public License for more
+ * details.
+ *
+ * You should have received a copy of the GNU General Public License along with
+ * this program.  If not, see <http://www.gnu.org/licenses/>.
+ *
+ * As a special exception, AlliedModders LLC gives you permission to link the
+ * code of this program (as well as its derivative works) to "Half-Life 2," the
+ * "Source Engine," the "SourcePawn JIT," and any Game MODs that run on software
+ * by the Valve Corporation.  You must obey the GNU General Public License in
+ * all respects for all other code used.  Additionally, AlliedModders LLC grants
+ * this exception to all derivative works.  AlliedModders LLC defines further
+ * exceptions, found in LICENSE.txt (as of this writing, version JULY-31-2007),
+ * or <http://www.sourcemod.net/license.php>.
+ *
+ * Version: $Id: admin-flatfile.sp 1438 2007-09-16 03:45:06Z dvander $
+ */
+
+
+DisplayVoteKickMenu(client, target)
+{
+	g_voteClient[VOTE_CLIENTID] = target;
+	g_voteClient[VOTE_USERID] = GetClientUserId(target);
+
+	GetClientName(target, g_voteInfo[VOTE_NAME], sizeof(g_voteInfo[]));
+
+	LogAction(client, target, "\"%L\" initiated a kick vote against \"%L\"", client, target);
+	ShowActivity(client, "%t", "Initiated Vote Kick", g_voteInfo[VOTE_NAME]);
+	
+	g_voteType = voteType:kick;
+	
+	g_hVoteMenu = CreateMenu(Handler_VoteCallback, MenuAction:MENU_ACTIONS_ALL);
+	SetMenuTitle(g_hVoteMenu, "Votekick Player");
+	AddMenuItem(g_hVoteMenu, VOTE_YES, "Yes");
+	AddMenuItem(g_hVoteMenu, VOTE_NO, "No");
+	SetMenuExitButton(g_hVoteMenu, false);
+	VoteMenuToAll(g_hVoteMenu, 20);
+
+}
+
+DisplayKickTargetMenu(client)
+{
+	new Handle:menu = CreateMenu(MenuHandler_Kick);
+	
+	decl String:title[100];
+	Format(title, sizeof(title), "%T:", "Kick vote", client);
+	SetMenuTitle(menu, title);
+	SetMenuExitBackButton(menu, true);
+	
+	AddTargetsToMenu(menu, client, false, false);
+	
+	DisplayMenu(menu, client, MENU_TIME_FOREVER);
+}
+
+public AdminMenu_VoteKick(Handle:topmenu, 
+							  TopMenuAction:action,
+							  TopMenuObject:object_id,
+							  param,
+							  String:buffer[],
+							  maxlength)
+{
+	if (action == TopMenuAction_DisplayOption)
+	{
+		Format(buffer, maxlength, "%T", "Kick vote", param);
+	}
+	else if (action == TopMenuAction_SelectOption)
+	{
+		DisplayKickTargetMenu(param);
+	}
+	else if (action == TopMenuAction_DrawOption)
+	{	
+		/* disable this option if a vote is already running */
+		buffer[0] = !IsNewVoteAllowed() ? ITEMDRAW_IGNORE : ITEMDRAW_DEFAULT;
+	}
+}
+
+public MenuHandler_Kick(Handle:menu, MenuAction:action, param1, param2)
+{
+	if (action == MenuAction_End)
+	{
+		CloseHandle(menu);
+	}
+	else if (action == MenuAction_Cancel)
+	{
+		if (param2 == MenuCancel_ExitBack && hTopMenu != INVALID_HANDLE)
+		{
+			DisplayTopMenu(hTopMenu, param1, TopMenuPosition_LastCategory);
+		}
+	}
+	else if (action == MenuAction_Select)
+	{
+		decl String:info[32], String:name[32];
+		new userid, target;
+		
+		GetMenuItem(menu, param2, info, sizeof(info), _, name, sizeof(name));
+		userid = StringToInt(info);
+
+		if ((target = GetClientOfUserId(userid)) == 0)
+		{
+			PrintToChat(param1, "[SM] %t", "Player no longer available");
+		}
+		else if (!CanUserTarget(param1, target))
+		{
+			PrintToChat(param1, "[SM] %t", "Unable to target");
+		}
+		else
+		{
+			g_voteArg[0] = '\0';
+			DisplayVoteKickMenu(param1, target);
+		}
+	}
+}
+
+public Action:Command_Votekick(client, args)
+{
+	if (args < 1)
+	{
+		ReplyToCommand(client, "[SM] Usage: sm_votekick <player> [reason]");
+		return Plugin_Handled;	
+	}
+	
+	if (IsVoteInProgress())
+	{
+		ReplyToCommand(client, "[SM] %t", "Vote in Progress");
+		return Plugin_Handled;
+	}	
+	
+	if (!TestVoteDelay(client))
+	{
+		return Plugin_Handled;
+	}
+	
+	decl String:text[256], String:arg[64];
+	GetCmdArgString(text, sizeof(text));
+	
+	new len = BreakString(text, arg, sizeof(arg));
+	
+	new target = FindTarget(client, arg);
+	if (target == -1)
+	{
+		return Plugin_Handled;
+	}
+	
+	if (len != -1)
+	{
+		strcopy(g_voteArg, sizeof(g_voteArg), text[len]);
+	}
+	else
+	{
+		g_voteArg[0] = '\0';
+	}
+	
+	DisplayVoteKickMenu(client, target);
+	
+	return Plugin_Handled;
+}
@@ -0,0 +1,283 @@
+/**
+ * vim: set ts=4 :
+ * =============================================================================
+ * SourceMod Basevotes Plugin
+ * Provides map functionality
+ *
+ * SourceMod (C)2004-2008 AlliedModders LLC.  All rights reserved.
+ * =============================================================================
+ *
+ * This program is free software; you can redistribute it and/or modify it under
+ * the terms of the GNU General Public License, version 3.0, as published by the
+ * Free Software Foundation.
+ * 
+ * This program is distributed in the hope that it will be useful, but WITHOUT
+ * ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
+ * FOR A PARTICULAR PURPOSE.  See the GNU General Public License for more
+ * details.
+ *
+ * You should have received a copy of the GNU General Public License along with
+ * this program.  If not, see <http://www.gnu.org/licenses/>.
+ *
+ * As a special exception, AlliedModders LLC gives you permission to link the
+ * code of this program (as well as its derivative works) to "Half-Life 2," the
+ * "Source Engine," the "SourcePawn JIT," and any Game MODs that run on software
+ * by the Valve Corporation.  You must obey the GNU General Public License in
+ * all respects for all other code used.  Additionally, AlliedModders LLC grants
+ * this exception to all derivative works.  AlliedModders LLC defines further
+ * exceptions, found in LICENSE.txt (as of this writing, version JULY-31-2007),
+ * or <http://www.sourcemod.net/license.php>.
+ *
+ * Version: $Id: admin-flatfile.sp 1438 2007-09-16 03:45:06Z dvander $
+ */
+
+new Handle:g_MapList = INVALID_HANDLE;
+new g_mapCount;
+
+new Handle:g_SelectedMaps;
+new bool:g_VoteMapInUse;
+
+DisplayVoteMapMenu(client, mapCount, String:maps[5][])
+{
+	LogAction(client, -1, "\"%L\" initiated a map vote.", client);
+	ShowActivity2(client, "[SM] ", "%t", "Initiated Vote Map");
+	
+	g_voteType = voteType:map;
+	
+	g_hVoteMenu = CreateMenu(Handler_VoteCallback, MenuAction:MENU_ACTIONS_ALL);
+	
+	if (mapCount == 1)
+	{
+		strcopy(g_voteInfo[VOTE_NAME], sizeof(g_voteInfo[]), maps[0]);
+			
+		SetMenuTitle(g_hVoteMenu, "Change Map To");
+		AddMenuItem(g_hVoteMenu, maps[0], "Yes");
+		AddMenuItem(g_hVoteMenu, VOTE_NO, "No");
+	}
+	else
+	{
+		g_voteInfo[VOTE_NAME][0] = '\0';
+		
+		SetMenuTitle(g_hVoteMenu, "Map Vote");
+		for (new i = 0; i < mapCount; i++)
+		{
+			AddMenuItem(g_hVoteMenu, maps[i], maps[i]);
+		}	
+	}
+	
+	SetMenuExitButton(g_hVoteMenu, false);
+	VoteMenuToAll(g_hVoteMenu, 20);		
+}
+
+ResetMenu()
+{
+	g_VoteMapInUse = false;
+	ClearArray(g_SelectedMaps);
+}
+
+ConfirmVote(client)
+{
+	new Handle:menu = CreateMenu(MenuHandler_Confirm);
+	
+	decl String:title[100];
+	Format(title, sizeof(title), "%T:", "Confirm Vote", client);
+	SetMenuTitle(menu, title);
+	SetMenuExitBackButton(menu, true);
+	
+	AddMenuItem(menu, "Confirm", "Start the Vote");
+	
+	DisplayMenu(menu, client, MENU_TIME_FOREVER);	
+}
+
+public MenuHandler_Confirm(Handle:menu, MenuAction:action, param1, param2)
+{
+	if (action == MenuAction_End)
+	{
+		CloseHandle(menu);
+		g_VoteMapInUse = false;
+	}
+	else if (action == MenuAction_Cancel)
+	{
+		ResetMenu();
+		
+		if (param2 == MenuCancel_ExitBack && hTopMenu != INVALID_HANDLE)
+		{
+			DisplayTopMenu(hTopMenu, param1, TopMenuPosition_LastCategory);
+		}
+	}
+	else if (action == MenuAction_Select)
+	{
+		decl String:maps[5][64];
+		new selectedmaps = GetArraySize(g_SelectedMaps);
+		
+		for (new i = 0; i < selectedmaps; i++)
+		{
+			GetArrayString(g_SelectedMaps, i, maps[i], sizeof(maps[]));
+		}
+		
+		DisplayVoteMapMenu(param1, selectedmaps, maps);
+		
+		ResetMenu();
+	}
+}
+
+public MenuHandler_Map(Handle:menu, MenuAction:action, param1, param2)
+{
+	if (action == MenuAction_Cancel)
+	{		
+		if (param2 == MenuCancel_ExitBack && hTopMenu != INVALID_HANDLE)
+		{
+			ConfirmVote(param1);
+		}
+		else // no action was selected.
+		{
+			/* Re-enable the menu option */
+			g_VoteMapInUse = false;
+			
+			ResetMenu();
+		}
+	}
+	else if (action == MenuAction_DrawItem)
+	{
+		decl String:info[32], String:name[32];
+		
+		GetMenuItem(menu, param2, info, sizeof(info), _, name, sizeof(name));
+		
+		if (FindStringInArray(g_SelectedMaps, info) != -1)
+		{
+			return ITEMDRAW_IGNORE;
+		}
+		else
+		{
+			return ITEMDRAW_DEFAULT;
+		}
+	}
+	else if (action == MenuAction_Select)
+	{
+		decl String:info[32], String:name[32];
+		
+		GetMenuItem(menu, param2, info, sizeof(info), _, name, sizeof(name));
+		
+		PushArrayString(g_SelectedMaps, info);
+		
+		/* Redisplay the list */
+		if (GetArraySize(g_SelectedMaps) < 5)
+		{
+			DisplayMenu(g_MapList, param1, MENU_TIME_FOREVER);
+		}
+		else
+		{
+			ConfirmVote(param1);
+		}
+	}
+	
+	return 0;
+}
+
+public AdminMenu_VoteMap(Handle:topmenu, 
+							  TopMenuAction:action,
+							  TopMenuObject:object_id,
+							  param,
+							  String:buffer[],
+							  maxlength)
+{
+	if (action == TopMenuAction_DisplayOption)
+	{
+		Format(buffer, maxlength, "%T", "Map vote", param);
+	}
+	else if (action == TopMenuAction_SelectOption)
+	{
+		g_VoteMapInUse = true;
+		ResetMenu();
+		DisplayMenu(g_MapList, param, MENU_TIME_FOREVER);
+	}
+	else if (action == TopMenuAction_DrawOption)
+	{	
+		/* disable this option if a vote is already running, theres no maps listed or someone else has already acessed this menu */
+		buffer[0] = (!IsNewVoteAllowed() || g_mapCount < 1 || g_VoteMapInUse) ? ITEMDRAW_IGNORE : ITEMDRAW_DEFAULT;
+	}
+}
+
+public Action:Command_Votemap(client, args)
+{
+	if (args < 1)
+	{
+		ReplyToCommand(client, "[SM] Usage: sm_votemap <mapname> [mapname2] ... [mapname5]");
+		return Plugin_Handled;	
+	}
+	
+	if (IsVoteInProgress())
+	{
+		ReplyToCommand(client, "[SM] %t", "Vote in Progress");
+		return Plugin_Handled;
+	}
+		
+	if (!TestVoteDelay(client))
+	{
+		return Plugin_Handled;
+	}
+	
+	decl String:text[256];
+	GetCmdArgString(text, sizeof(text));
+
+	decl String:maps[5][64];
+	new mapCount;	
+	new len, pos;
+	
+	while (pos != -1 && mapCount < 5)
+	{	
+		pos = BreakString(text[len], maps[mapCount], sizeof(maps[]));
+		
+		if (!IsMapValid(maps[mapCount]))
+		{
+			ReplyToCommand(client, "[SM] %t", "Map was not found", maps[mapCount]);
+			return Plugin_Handled;
+		}		
+
+		mapCount++;
+		
+		if (pos != -1)
+		{
+			len += pos;
+		}	
+	}
+
+	DisplayVoteMapMenu(client, mapCount, maps);
+	
+	return Plugin_Handled;	
+}
+
+new Handle:g_map_array = INVALID_HANDLE;
+new g_map_serial = -1;
+
+LoadMapList(Handle:menu)
+{
+	new Handle:map_array;
+	
+	if ((map_array = ReadMapList(g_map_array,
+			g_map_serial,
+			"sm_votemap menu",
+			MAPLIST_FLAG_CLEARARRAY|MAPLIST_FLAG_NO_DEFAULT|MAPLIST_FLAG_MAPSFOLDER))
+		!= INVALID_HANDLE)
+	{
+		g_map_array = map_array;
+	}
+	
+	if (g_map_array == INVALID_HANDLE)
+	{
+		return 0;
+	}
+	
+	RemoveAllMenuItems(menu);
+	
+	decl String:map_name[64];
+	new map_count = GetArraySize(g_map_array);
+	
+	for (new i = 0; i < map_count; i++)
+	{
+		GetArrayString(g_map_array, i, map_name, sizeof(map_name));
+		AddMenuItem(menu, map_name, map_name);
+	}
+	
+	return map_count;
+}